// -*-C++-*-
#version 120

// Duplicated from model-ALS-base.frag, but in the form of
// library functions that can be used by other shader code

varying vec4 diffuse_term;
varying vec3 normal;
varying vec3 relPos;
varying vec4 ecPosition;

varying float yprime_alt;
varying float mie_angle;

uniform float visibility;
uniform float avisibility;
uniform float scattering;
uniform float terminator;
uniform float terrain_alt;
uniform float hazeLayerAltitude;
uniform float overcast;
uniform float eye_alt;
uniform float cloud_self_shading;
uniform float air_pollution;
uniform float landing_light1_offset;
uniform float landing_light2_offset;
uniform float landing_light3_offset;

uniform int quality_level;
uniform int tquality_level;
uniform int use_searchlight;
uniform int use_landing_light;
uniform int use_alt_landing_light;


const float EarthRadius = 5800000.0;
const float terminator_width = 200000.0;

float alt;
float eShade;


float fog_func (in float targ, in float alt);
float rayleigh_in_func(in float dist, in float air_pollution, in float avisibility, in float eye_alt, in float vertex_alt);
float alt_factor(in float eye_alt, in float vertex_alt);
float light_distance_fading(in float dist);
float fog_backscatter(in float avisibility);


vec3 rayleigh_out_shift(in vec3 color, in float outscatter);
vec3 get_hazeColor(in float light_arg);
vec3 searchlight();
vec3 landing_light(in float offset, in float offsetv);
vec3 filter_combined (in vec3 color) ;

float getShadowing();
vec3 getClusteredLightsContribution(vec3 p, vec3 n, vec3 texel);

float luminance(vec3 color)
{
    return dot(vec3(0.212671, 0.715160, 0.072169), color);
}


float light_func (in float x, in float a, in float b, in float c, in float d, in float e)
{
    x = x - 0.5;

    // use the asymptotics to shorten computations
    if (x > 30.0) {return e;}
    if (x < -15.0) {return 0.0;}

    return e / pow((1.0 + a * exp(-b * (x-c)) ),(1.0/d));
}

// this determines how light is attenuated in the distance
// physically this should be exp(-arg) but for technical reasons we use a sharper cutoff
// for distance > visibility


void render_model_ALS_base(in vec4 texel)
{
    vec3 shadedFogColor = vec3(0.55, 0.67, 0.88);
    // this is taken from default.frag
    vec3 n;
    float NdotL, NdotHV, fogFactor;
    vec4 color = gl_Color;
    vec3 lightDir = gl_LightSource[0].position.xyz;
    vec3 halfVector = gl_LightSource[0].halfVector.xyz;

    vec4 fragColor;
    vec4 specular = vec4(0.0);
    float intensity;

    float effective_scattering = min(scattering, cloud_self_shading);

    eShade = 1.0 - 0.9 * smoothstep(-terminator_width+ terminator, terminator_width + terminator, yprime_alt);
    vec4 light_specular = gl_LightSource[0].specular * (eShade - 0.1);

    // If gl_Color.a == 0, this is a back-facing polygon and the
    // normal should be reversed.
    n = (2.0 * gl_Color.a - 1.0) * normal;
    n = normalize(n);

    NdotL = dot(n, lightDir);
    if (NdotL > 0.0) {
        float shadowmap = getShadowing();
        color += diffuse_term * NdotL * shadowmap;
        NdotHV = max(dot(n, halfVector), 0.0);
        if (gl_FrontMaterial.shininess > 0.0)
            specular.rgb = (gl_FrontMaterial.specular.rgb
                            * light_specular.rgb
                            * pow(NdotHV, gl_FrontMaterial.shininess)
                            * shadowmap);
    }
    color.a = diffuse_term.a;
    // This shouldn't be necessary, but our lighting becomes very
    // saturated. Clamping the color before modulating by the texture
    // is closer to what the OpenGL fixed function pipeline does.
    color = clamp(color, 0.0, 1.0);

    float dist = length(relPos);
    vec3 secondary_light = vec3 (0.0,0.0,0.0);

    if ((quality_level > 5) && (tquality_level > 5)) {
        if (use_searchlight == 1) {
            secondary_light += searchlight();
        }
        if (use_landing_light == 1) {
            secondary_light += landing_light(landing_light1_offset, landing_light3_offset);
        }
        if (use_alt_landing_light == 1) {
            secondary_light += landing_light(landing_light2_offset, landing_light3_offset);
        }
        if (dist > 2.0) {// we don't want to light the cockpit...
            color.rgb +=secondary_light * light_distance_fading(dist);
        }
    }

    fragColor = color * texel + specular;
    fragColor.rgb += getClusteredLightsContribution(ecPosition.xyz, n, texel.rgb);


    float lightArg = (terminator-yprime_alt)/100000.0;

    vec3 hazeColor = get_hazeColor(lightArg);


    // Rayleigh color shift due to in-scattering

    if ((quality_level > 5) && (tquality_level > 5)) {
        float rayleigh_length = 0.5 * avisibility * (2.5 - 1.9 * air_pollution)/alt_factor(eye_alt, eye_alt+relPos.z);
        float outscatter = 1.0-exp(-dist/rayleigh_length);
        fragColor.rgb = rayleigh_out_shift(fragColor.rgb,outscatter);
        float rShade = 1.0 - 0.9 * smoothstep(-terminator_width+ terminator, terminator_width + terminator, yprime_alt + 420000.0);
        float lightIntensity = length(hazeColor * effective_scattering) * rShade;
        vec3 rayleighColor = vec3 (0.17, 0.52, 0.87) * lightIntensity;
        float rayleighStrength = rayleigh_in_func(dist, air_pollution, avisibility/max(lightIntensity,0.05), eye_alt, eye_alt + relPos.z);
        fragColor.rgb = mix(fragColor.rgb, rayleighColor,rayleighStrength);
    }


    // here comes the terrain haze model
    float delta_z = hazeLayerAltitude - eye_alt;
    float mvisibility = min(visibility, avisibility);

    if (dist > 0.04 * mvisibility) {
        alt = eye_alt;

        float transmission;
        float vAltitude;
        float delta_zv;
        float H;
        float distance_in_layer;
        float transmission_arg;

        // angle with horizon
        float ct = dot(vec3(0.0, 0.0, 1.0), relPos)/dist;

        // we solve the geometry what part of the light path is attenuated normally and what is through the haze layer
        if (delta_z > 0.0) { // we're inside the layer
            if (ct < 0.0) { // we look down
                distance_in_layer = dist;
                vAltitude = min(distance_in_layer,mvisibility) * ct;
                delta_zv = delta_z - vAltitude;
            } else {   // we may look through upper layer edge
                H = dist * ct;
                if (H > delta_z) {
                    distance_in_layer = dist/H * delta_z;
                } else {
                    distance_in_layer = dist;
                }
                vAltitude = min(distance_in_layer,visibility) * ct;
                delta_zv = delta_z - vAltitude;
            }
        } else { // we see the layer from above, delta_z < 0.0
            H = dist * -ct;
            if (H  < (-delta_z)) { // we don't see into the layer at all, aloft visibility is the only fading
                distance_in_layer = 0.0;
                delta_zv = 0.0;
            } else {
                vAltitude = H + delta_z;
                distance_in_layer = vAltitude/H * dist;
                vAltitude = min(distance_in_layer,visibility) * (-ct);
                delta_zv = vAltitude;
            }
        }

        // ground haze cannot be thinner than aloft visibility in the model,
        // so we need to use aloft visibility otherwise

        transmission_arg = (dist-distance_in_layer)/avisibility;

        float eqColorFactor;

        //float scattering = ground_scattering + (1.0 - ground_scattering) * smoothstep(hazeLayerAltitude -100.0, hazeLayerAltitude + 100.0, relPos.z + eye_alt);
        if (visibility < avisibility) {
            transmission_arg = transmission_arg + (distance_in_layer/visibility);
            // this combines the Weber-Fechner intensity
            eqColorFactor = 1.0 - 0.1 * delta_zv/visibility - (1.0 -effective_scattering);
        } else {
            transmission_arg = transmission_arg + (distance_in_layer/avisibility);
            // this combines the Weber-Fechner intensity
            eqColorFactor = 1.0 - 0.1 * delta_zv/avisibility - (1.0 -effective_scattering);
        }

        transmission =  fog_func(transmission_arg, alt);

        // there's always residual intensity, we should never be driven to zero
        if (eqColorFactor < 0.2) eqColorFactor = 0.2;

        // Mie-like factor
        if (lightArg < 10.0) {
            intensity = length(hazeColor);
            float mie_magnitude = 0.5 * smoothstep(350000.0, 150000.0, terminator-sqrt(2.0 * EarthRadius * terrain_alt));
            hazeColor = intensity * ((1.0 - mie_magnitude) + mie_magnitude * mie_angle) * normalize(mix(hazeColor,  vec3 (0.5, 0.58, 0.65), mie_magnitude * (0.5 - 0.5 * mie_angle)) );
        }

        // high altitude desaturation of the haze color
        intensity = length(hazeColor);
        hazeColor = intensity * normalize (mix(hazeColor, intensity * vec3 (1.0,1.0,1.0), 0.7* smoothstep(5000.0, 50000.0, alt)));

        // blue hue of haze
        hazeColor.x = hazeColor.x * 0.83;
        hazeColor.y = hazeColor.y * 0.9;

        // additional blue in indirect light
        float fade_out = max(0.65 - 0.3 *overcast, 0.45);
        intensity = length(hazeColor);
        hazeColor = intensity * normalize(mix(hazeColor,  1.5* shadedFogColor, 1.0 -smoothstep(0.25, fade_out,eShade) ));

        // change haze color to blue hue for strong fogging
        //intensity = length(hazeColor);
        hazeColor = intensity * normalize(mix(hazeColor,  shadedFogColor, (1.0-smoothstep(0.5,0.9,eqColorFactor))));

        // reduce haze intensity when looking at shaded surfaces, only in terminator region

        float shadow = mix( min(1.0 + dot(normal,lightDir),1.0), 1.0, 1.0-smoothstep(0.1, 0.4, transmission));
        hazeColor = mix(shadow * hazeColor, hazeColor, 0.3 + 0.7* smoothstep(250000.0, 400000.0, terminator));

        // don't let the light fade out too rapidly

        lightArg = (terminator + 200000.0)/100000.0;
        float minLightIntensity = min(0.2,0.16 * lightArg + 0.5);
        vec3 minLight = minLightIntensity * vec3 (0.2, 0.3, 0.4);
        hazeColor *= eqColorFactor * eShade;
        hazeColor.rgb = max(hazeColor.rgb, minLight.rgb);

        // determine the right mix of transmission and haze
        fragColor.rgb = mix(hazeColor  + secondary_light * fog_backscatter(mvisibility), fragColor.rgb,transmission);

    }

    fragColor.rgb = filter_combined(fragColor.rgb);

    gl_FragColor = fragColor;
}