HDR: Add night vision effect

Effects/HDR/postprocess.eff

@@ -8,6 +8,8 @@
     <alpha><use>/sim/rendering/redout/alpha</use></alpha>
     <red><use>/sim/rendering/redout/red</use></red>
     <max-distorsion-amount type="float">0.2</max-distorsion-amount>
+    <!-- night_vision.glsl -->
+    <night-vision-enabled><use>/sim/rendering/hdr/night-vision/enabled</use></night-vision-enabled>
   </parameters>
   <technique n="1">
     <pass>
@@ -17,8 +19,9 @@
         <fragment-shader>Shaders/HDR/math.glsl</fragment-shader>
         <fragment-shader>Shaders/HDR/color.glsl</fragment-shader>
         <fragment-shader>Shaders/HDR/aces.glsl</fragment-shader>
-        <fragment-shader>Shaders/HDR/redout.glsl</fragment-shader>
         <fragment-shader>Shaders/HDR/noise.glsl</fragment-shader>
+        <fragment-shader>Shaders/HDR/redout.glsl</fragment-shader>
+        <fragment-shader>Shaders/HDR/night_vision.glsl</fragment-shader>
       </program>
       <uniform>
         <name>hdr_tex</name>
@@ -56,6 +59,12 @@
         <type>float</type>
         <value><use>max-distorsion-amount</use></value>
       </uniform>
+      <!-- night_vision.glsl -->
+      <uniform>
+        <name>night_vision_enabled</name>
+        <type>bool</type>
+        <value><use>night-vision-enabled</use></value>
+      </uniform>
     </pass>
   </technique>
 </PropertyList>

Shaders/HDR/night_vision.glsl

@@ -0,0 +1,33 @@
+#version 330 core
+
+uniform bool night_vision_enabled;
+
+uniform vec4 fg_Viewport;
+uniform float osg_SimulationTime;
+
+const float FLICKER_AMOUNT = 0.05;
+const float NOISE_AMOUNT = 0.03;
+const float GRAIN_SIZE = 3.0;
+
+// color.glsl
+float linear_srgb_to_luminance(vec3 color);
+// noise.glsl
+float rand_1d(float n);
+float snoise_3d(vec3 v);
+
+vec3 night_vision_apply(vec3 color, vec2 uv)
+{
+    if (!night_vision_enabled) {
+        return color;
+    }
+    float lum = linear_srgb_to_luminance(color);
+    float noise = snoise_3d(vec3(uv * fg_Viewport.zw / GRAIN_SIZE, osg_SimulationTime * 10.0));
+    lum += noise * NOISE_AMOUNT;
+    float flicker = rand_1d(osg_SimulationTime) * FLICKER_AMOUNT;
+    vec3 green_factor = vec3(0.1, 1.0 - FLICKER_AMOUNT + flicker, 0.2);
+    color = lum * green_factor;
+    // Add vignetting
+    float d = distance(uv, vec2(0.5));
+    color *= smoothstep(0.7, 0.2, d);
+    return color;
+}

Shaders/HDR/noise.glsl

@@ -19,6 +19,11 @@
 
 #version 330 core
 
+float rand_1d(float n)
+{
+    return fract(sin(n) * 43758.5453123);
+}
+
 float rand_2d(vec2 co)
 {
     return fract(sin(dot(co.xy, vec2(12.9898,78.233))) * 43758.5453);
@@ -159,3 +164,101 @@ float voronoi_noise_2d(vec2 coord, float wavelength, float xrand, float yrand)
 {
     return voronoi_noise_2d(coord / wavelength, xrand, yrand);
 }
+
+/*
+ * 3D Simplex noise by Ian McEwan, Ashima Arts.
+ * Copyright (C) 2011 Ashima Arts. All rights reserved.
+ * Distributed under the MIT License.
+ * https://github.com/ashima/webgl-noise
+ */
+
+vec3 mod289(vec3 x) {
+    return x - floor(x * (1.0 / 289.0)) * 289.0;
+}
+
+vec4 mod289(vec4 x) {
+    return x - floor(x * (1.0 / 289.0)) * 289.0;
+}
+
+vec4 permute(vec4 x) {
+    return mod289(((x*34.0)+10.0)*x);
+}
+
+vec4 taylor_inv_sqrt(vec4 r) {
+    return 1.79284291400159 - 0.85373472095314 * r;
+}
+
+float snoise_3d(vec3 v)
+{
+    const vec2 C = vec2(1.0/6.0, 1.0/3.0);
+    const vec4 D = vec4(0.0, 0.5, 1.0, 2.0);
+
+    // First corner
+    vec3 i  = floor(v + dot(v, C.yyy) );
+    vec3 x0 =   v - i + dot(i, C.xxx) ;
+
+    // Other corners
+    vec3 g = step(x0.yzx, x0.xyz);
+    vec3 l = 1.0 - g;
+    vec3 i1 = min( g.xyz, l.zxy );
+    vec3 i2 = max( g.xyz, l.zxy );
+
+    //   x0 = x0 - 0.0 + 0.0 * C.xxx;
+    //   x1 = x0 - i1  + 1.0 * C.xxx;
+    //   x2 = x0 - i2  + 2.0 * C.xxx;
+    //   x3 = x0 - 1.0 + 3.0 * C.xxx;
+    vec3 x1 = x0 - i1 + C.xxx;
+    vec3 x2 = x0 - i2 + C.yyy; // 2.0*C.x = 1/3 = C.y
+    vec3 x3 = x0 - D.yyy;      // -1.0+3.0*C.x = -0.5 = -D.y
+
+    // Permutations
+    i = mod289(i);
+    vec4 p = permute( permute( permute(
+                                   i.z + vec4(0.0, i1.z, i2.z, 1.0 ))
+                               + i.y + vec4(0.0, i1.y, i2.y, 1.0 ))
+                      + i.x + vec4(0.0, i1.x, i2.x, 1.0 ));
+
+    // Gradients: 7x7 points over a square, mapped onto an octahedron.
+    // The ring size 17*17 = 289 is close to a multiple of 49 (49*6 = 294)
+    float n_ = 0.142857142857; // 1.0/7.0
+    vec3  ns = n_ * D.wyz - D.xzx;
+
+    vec4 j = p - 49.0 * floor(p * ns.z * ns.z);  //  mod(p,7*7)
+
+    vec4 x_ = floor(j * ns.z);
+    vec4 y_ = floor(j - 7.0 * x_ );    // mod(j,N)
+
+    vec4 x = x_ *ns.x + ns.yyyy;
+    vec4 y = y_ *ns.x + ns.yyyy;
+    vec4 h = 1.0 - abs(x) - abs(y);
+
+    vec4 b0 = vec4( x.xy, y.xy );
+    vec4 b1 = vec4( x.zw, y.zw );
+
+    //vec4 s0 = vec4(lessThan(b0,0.0))*2.0 - 1.0;
+    //vec4 s1 = vec4(lessThan(b1,0.0))*2.0 - 1.0;
+    vec4 s0 = floor(b0)*2.0 + 1.0;
+    vec4 s1 = floor(b1)*2.0 + 1.0;
+    vec4 sh = -step(h, vec4(0.0));
+
+    vec4 a0 = b0.xzyw + s0.xzyw*sh.xxyy ;
+    vec4 a1 = b1.xzyw + s1.xzyw*sh.zzww ;
+
+    vec3 p0 = vec3(a0.xy,h.x);
+    vec3 p1 = vec3(a0.zw,h.y);
+    vec3 p2 = vec3(a1.xy,h.z);
+    vec3 p3 = vec3(a1.zw,h.w);
+
+    //Normalise gradients
+    vec4 norm = taylor_inv_sqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
+    p0 *= norm.x;
+    p1 *= norm.y;
+    p2 *= norm.z;
+    p3 *= norm.w;
+
+    // Mix final noise value
+    vec4 m = max(0.5 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), 0.0);
+    m = m * m;
+    return 105.0 * dot( m*m, vec4( dot(p0,x0), dot(p1,x1),
+                                   dot(p2,x2), dot(p3,x3) ) );
+}

Shaders/HDR/postprocess.frag

@@ -18,11 +18,13 @@ const float NOISE_GRANULARITY = 0.5 / 255.0;
 vec3 eotf_sRGB(vec3 linear_srgb);
 // aces.glsl
 vec3 aces_fitted(vec3 color);
+// noise.glsl
+float rand_2d(vec2 co);
 // redout.glsl
 vec2 redout_distort(vec2 uv);
 vec3 redout_apply(vec3 color, vec2 uv);
-// noise.glsl
-float rand_2d(vec2 co);
+// night-vision.glsl
+vec3 night_vision_apply(vec3 color, vec2 uv);
 
 vec3 get_debug_color(float value)
 {
@@ -65,6 +67,8 @@ void main()
     hdr_color = mix(hdr_color, bloom, bloom_strength);
     // Tonemap
     vec3 color = aces_fitted(hdr_color);
+    // Apply night vision filter
+    color = night_vision_apply(color, uv);
     // Apply blackout/redout
     color = redout_apply(color, uv);
     // Gamma correction

defaults.xml

@@ -569,6 +569,9 @@ Started September 2000 by David Megginson, david@megginson.com
           <sss-max-distance type="float">0.2</sss-max-distance>
           <sss-depth-bias type="float">0.00001</sss-depth-bias>
         </shadows>
+        <night-vision>
+          <enabled type="bool">false</enabled>
+        </night-vision>
         <debug>
           <display-ev100 type="bool">false</display-ev100>
           <show-gbuffer type="bool">false</show-gbuffer>