fgdata/Shaders/ubershader.frag

// -*- mode: C; -*-
// Licence: GPL v2
// Authors: Frederic Bouvier and Gijs de Rooy
// with major additions and revisions by
// Emilian Huminiuc and Vivian Meazza 2011
#version 120

varying	vec3 	rawpos;
varying	vec3 	VNormal;
varying	vec3 	VTangent;
varying	vec3 	VBinormal;
varying	vec3 	vViewVec;
varying	vec3 	reflVec;

varying	float	alpha;

uniform samplerCube Environment;
uniform sampler2D BaseTex;
uniform sampler2D NormalTex;
uniform sampler2D LightMapTex;
uniform sampler2D ReflMapTex;
uniform sampler2D ReflFresnelTex;
uniform sampler2D ReflRainbowTex;
uniform sampler3D ReflNoiseTex;

uniform int nmap_enabled;
uniform int nmap_dds;
uniform int nmap_tile;
uniform int refl_enabled;
uniform int refl_map;
uniform int lightmap_enabled;
uniform int lightmap_multi;
uniform int shader_qual;
uniform int dirt_enabled;
uniform int dirt_multi;

uniform float lightmap_r_factor;
uniform float lightmap_g_factor;
uniform float lightmap_b_factor;
uniform float lightmap_a_factor;
uniform float refl_correction;
uniform float refl_fresnel;
uniform float refl_rainbow;
uniform float refl_noise;
uniform float amb_correction;
uniform float dirt_r_factor;
uniform float dirt_g_factor;
uniform float dirt_b_factor;

uniform vec3 lightmap_r_color;
uniform vec3 lightmap_g_color;
uniform vec3 lightmap_b_color;
uniform vec3 lightmap_a_color;

uniform vec3 dirt_r_color;
uniform vec3 dirt_g_color;
uniform vec3 dirt_b_color;

///fog include//////////////////////
uniform int fogType;
vec3 fog_Func(vec3 color, int type);
////////////////////////////////////

void main (void)
{
	vec4 texel      = texture2D(BaseTex, gl_TexCoord[0].st);
	vec4 nmap       = texture2D(NormalTex, gl_TexCoord[0].st * nmap_tile);
	vec4 reflmap    = texture2D(ReflMapTex, gl_TexCoord[0].st);
	vec4 noisevec   = texture3D(ReflNoiseTex, rawpos.xyz);
	vec4 lightmapTexel = texture2D(LightMapTex, gl_TexCoord[0].st);

	vec3 mixedcolor;
	vec3 N;
	float pf;

///BEGIN bump
 	if (nmap_enabled > 0 && shader_qual > 2){
		N = nmap.rgb * 2.0 - 1.0;
		N = normalize(N.x * VTangent + N.y * VBinormal + N.z * VNormal);
		if (nmap_dds > 0)
  			N = -N;
 	} else {
 		N = normalize(VNormal);
 	}
///END bump
	vec4 reflection = textureCube(Environment, reflVec * dot(N,VNormal));
	vec3 viewVec = normalize(vViewVec);
	float v      = dot(viewVec, normalize(VNormal));// Map a rainbowish color
	vec4 fresnel = texture2D(ReflFresnelTex, vec2(v, 0.0));
	vec4 rainbow = texture2D(ReflRainbowTex, vec2(v, 0.0));

	float nDotVP = max(0.0, dot(N, normalize(gl_LightSource[0].position.xyz)));
	float nDotHV = max(0.0, dot(N, normalize(gl_LightSource[0].halfVector.xyz)));
	//glare on the backside of tranparent objects
	if ((gl_FrontMaterial.diffuse.a < 1.0 || texel.a < 1.0) && dot(N, normalize(gl_LightSource[0].position.xyz)) < 0.0) {
		nDotVP = max(0.0, dot(-N, normalize(gl_LightSource[0].position.xyz)));
		nDotHV = max(0.0, dot(-N, normalize(gl_LightSource[0].halfVector.xyz)));
	}

	if (nDotVP == 0.0)
		pf = 0.0;
	else
		pf = pow(nDotHV, gl_FrontMaterial.shininess);

	vec4 Diffuse  = gl_LightSource[0].diffuse * nDotVP;
	vec4 Specular = gl_FrontMaterial.specular * gl_LightSource[0].specular * pf;

	vec4 color = gl_Color + Diffuse * gl_FrontMaterial.diffuse;
	color += Specular * gl_FrontMaterial.specular * nmap.a;
	color = clamp( color, 0.0, 1.0 );

////////////////////////////////////////////////////////////////////
//BEGIN reflect
////////////////////////////////////////////////////////////////////
	if (refl_enabled > 0 && shader_qual > 1){
		float reflFactor;
		float transparency_offset = clamp(refl_correction, -1.0, 1.0);// set the user shininess offset

		if(refl_map > 0){
			// map the shininess of the object with user input
			//float pam = (map.a * -2) + 1; //reverse map
			reflFactor = reflmap.a + transparency_offset;
		} else if (nmap_enabled > 0 && shader_qual > 2) {
			// set the reflectivity proportional to shininess with user input
			reflFactor = (gl_FrontMaterial.shininess / 128.0) * nmap.a + transparency_offset;
		} else {
			reflFactor = gl_FrontMaterial.shininess/128.0 + transparency_offset;
		}
		reflFactor = clamp(reflFactor, 0.0, 1.0);

		// add fringing fresnel and rainbow effects and modulate by reflection
		vec4 reflcolor = mix(reflection, rainbow, refl_rainbow * v);
		reflcolor += Specular * nmap.a;
		vec4 reflfrescolor = mix(reflcolor, fresnel, refl_fresnel  * v);
		vec4 noisecolor = mix(reflfrescolor, noisevec, refl_noise);
		vec4 raincolor = vec4(noisecolor.rgb * reflFactor, 1.0);
		raincolor += Specular * nmap.a;

		mixedcolor = mix(texel, raincolor, reflFactor).rgb;
 	} else {
 		mixedcolor = texel.rgb;
 	}
 	/////////////////////////////////////////////////////////////////////
 	//END reflect
 	/////////////////////////////////////////////////////////////////////

 	//////////////////////////////////////////////////////////////////////
 	//begin DIRT
 	//////////////////////////////////////////////////////////////////////
 	if (dirt_enabled > 0.0){
		float dirtFactorR = reflmap.r * dirt_r_factor;
		dirtFactorR = smoothstep(0.0, 1.0, dirtFactorR);
		mixedcolor.rgb = mix(mixedcolor.rgb, dirt_r_color, dirtFactorR);
		if (dirt_multi > 0) {
			float dirtFactorG = reflmap.g * dirt_g_factor;
			float dirtFactorB = reflmap.b * dirt_b_factor;
			dirtFactorG = smoothstep(0.0, 1.0, dirtFactorG);
			dirtFactorB = smoothstep(0.0, 1.0, dirtFactorB);
			mixedcolor.rgb = mix(mixedcolor.rgb, dirt_g_color, dirtFactorG);
			mixedcolor.rgb = mix(mixedcolor.rgb, dirt_b_color, dirtFactorB);
		}
	}
	//////////////////////////////////////////////////////////////////////
	//END Dirt
	//////////////////////////////////////////////////////////////////////


	// set ambient adjustment to remove bluiness with user input
	float ambient_offset = clamp(amb_correction, -1.0, 1.0);
	vec4 ambient_Correction = vec4(gl_LightSource[0].ambient.rg, gl_LightSource[0].ambient.b * 0.6, 0.5) * ambient_offset ;
	ambient_Correction = clamp(ambient_Correction, -1.0, 1.0);

	color.a = texel.a * alpha;
	vec4 fragColor = vec4(color.rgb * mixedcolor + ambient_Correction.rgb, color.a);



	fragColor += Specular * nmap.a;

//////////////////////////////////////////////////////////////////////
// BEGIN lightmap
//////////////////////////////////////////////////////////////////////
	if ( lightmap_enabled >= 1 ) {
		vec3 lightmapcolor;
		if (lightmap_multi >0 ){
			lightmapcolor = lightmap_r_color * lightmap_r_factor * lightmapTexel.r +
			                lightmap_g_color * lightmap_g_factor * lightmapTexel.g +
			                lightmap_b_color * lightmap_b_factor * lightmapTexel.b +
			                lightmap_a_color * lightmap_a_factor * lightmapTexel.a ;
		} else {
			lightmapcolor = lightmapTexel.rgb * lightmap_r_color * lightmap_r_factor;
		}
		fragColor.rgb = max(fragColor.rgb, lightmapcolor * gl_FrontMaterial.diffuse.rgb * mixedcolor);
	}
//////////////////////////////////////////////////////////////////////
// END lightmap
/////////////////////////////////////////////////////////////////////

	fragColor.rgb = fog_Func(fragColor.rgb, fogType);
	gl_FragColor = fragColor;
}